Программное изменение кода.

Обратите внимание на это, в VBA нет функции eval(), которая есть в JavaScript, поэтому программно сформировать, а потом выполнить произвольный программный код несколько сложнее, не ясно, как перейти от имени объекта к самому объекту.

Для решения второй задачи рекомендуется всегда создаваемые объекты помещать в коллекцию, давая имя элементу коллекции такое же, как имя объекта. В таком случае в дальнейшем можно обратиться к элементу коллекции по имени, получая тем самым объект.

Рассмотрим пример. Пусть в проекте описан класс с именем fragm:

Public name As String, val As Integer

Private Sub Class_Initialize()

name = "f" & Int(Rnd * 10000) 'формирование случайного имени вида f567

val = Rnd * 20 + 10 ' случайное значение от 10 до 30

End Sub

В форме заводим список имен формируемых экземпляров

Dim cl_f As New Collection

Private Sub UserForm_Initialize()

Dim f As fragm, i As Integer

Randomize

For i = 1 To 10

Set f = New fragm

cl_f.Add f, f.name

ListBox1.AddItem f.name

Next

End Sub

По щелчку пользователя на пункт списка выдается сообщение – значение элемента коллекции с выбранным именем.

Private Sub ListBox1_Click()

MsgBox cl_f(ListBox1.List(ListBox1.ListIndex)).val

End Sub

Объект VBE предоставляет возможности для программного изменения операторов. В коллекции проектов содержатся проекты всех открытых документов. Компоненты – это ThisDocument, формы, модули, модули классов в том порядке, в каком они указаны в окне проекта. К любому из них можно обратиться по номеру или по имени. Свойство CodeModule предоставляет объект, с помощью которого можно работать с программными инструкциями. Можно изменять строки, можно удалять и добавлять строки, можно добавлять текст из строки или из текстового файла.

В примере текст программы содержится в модуле1 (никаких форм нет). В программе сначала удаляется строка из макроса changecode, затем вставляется другая строка и вызывается измененный макрос. Комбинация Chr(34) возвращает знак «кавычки».

Sub try()

j = 2: ns = 11

With VBE.VBProjects(1).VBComponents(j).CodeModule

.DeleteLines ns, 1

.InsertLines ns, "MsgBox " & Chr(34) & "22222" & Chr(34)

End With

changcode

End Sub

 

Sub changcode()

MsgBox "11111"

End Sub

Динамические массивы

При описании массива не всегда можно заранее, на стадии написании программы, знать, сколько элементов будет в массиве. Например, это выбирает пользователь. Или количество элементов определяется файлом-источником и т.п. С другой стороны некоторые вычислительные методы могут в процессе расчетов уменьшать количество «рабочих» элементов, при этом хотелось бы освобождать не нужную память.

Для реализации всего вышеизложенного нам поможет инструкция ReDim. Сначала может быть описан динамический массив, например, так:

Dim имямассива () [As type]

Обратите внимание на то, что указывается имя массива и не обязательно указывается тип элементов, но не указывается количество элементов. В дальнейшем можно уточнить описание этого массива, задав количество элементов. Синтаксис инструкции:

ReDim имямассива (границы) [As type]

Ключевое место в этой инструкции – описание границ изменения индексов. Это описание выглядит следующим образом:

[нижняяграница to] верхняяграница, [нижняяграница to] верхняяграница, …

Для каждого индекса можно задать начальное и конечное значение. Если не задавать начальное, то оно определяется по умолчанию (указано в настройках) либо задается при помощи инструкции Option Base.

Option base 1 'установка нижней границы индексов по умолчанию = 1.

Dim Lower

Dim MyArray(20), TwoDArray(3, 4)

Dim ZeroArray(0 To 5) ' здесь явно указаноа нижняя граница индекса.

Lower = LBound(MyArray) ' функция возвращает значение нижней границы массива =1

Lower = LBound(TwoDArray, 2) ' вернет 1.

Lower = LBound(ZeroArray) ' вернет 0.

Можно переописывать массив неоднократно.

ReDim [Preserve] имямассива (границы) [As type]

Здесь важно, что можно изменять границы индексов. Но самое интересное это то, что можно потребовать сохранить все значения в «старых» элементах (Preserve). При применении слова Preserve можно изменять только последнюю размерность.

ReDim X(10, 10, 10)

...

ReDim Preserve X(10, 10, 15)

Еще один важный момент: память, выделенная под статический массив, то есть массив, количество элементов которого задано в инструкции Dim, освобождается только по завершению процедуры или функции, в которой этот массив описан. Если массив описан на уровне модуля, то память, занятая им, освобождается по закрытию документа. Такая расточительность кажется неприемлемой. Для динамических массивов есть замечательная инструкция Erase, которая освобождает память, занятую массивом.